ソフトウェア/Igor/システムの基本 のバックアップ(No.5)

イディオム †

モジュール名のデータフォルダの中に特定の文字列変数を用意して、 そこに呼び出してもらいたい関数名を書いておくと適当なタイミングで 呼んでもらえるようにする。

例えばそのモジュールではある画像を表示する役割を持っていて、 画像上をクリックするとその点の座標を引数に、 （登録されていれば）そのコールバック関数を呼ぶような場合。

モジュール名を Module1.ipf とすると、

Module1.ipf 内で、

LANG:Igor
// コールバック関数のプロトタイプ
// x, y には画像上でクリックした座標が入る
function ImageClickProcProto(x, y)
variable x, y
end

// 画像をクリックしたときにモジュール内で呼び出される。
// 必要に応じてユーザー指定のコールバック関数を呼ぶ
static function ImageClicked(x, y)
variable x, y
    // モジュール名と同じ名前のデータフォルダー root:Packages:Module1 に 
    // ImageClickProc という文字列変数が定義されていて
    SVAR/Z ImageClickProc = root:Packages:Module1:ImageClickProc
    if (SVAR_exists(ImageClickProc))
        // その文字列が示す名前のユーザー定義関数が存在するなら
        if (exists(ImageClickProc)==6)
            // その関数を呼び出す
            FUNCREF ImageClickProcProto ImageClickProcRef = $(ImageClickProc)
            ImageClickProcRef(x, y)
        endif
    endif
end

Module1 を使う側では、

LANG:Igor
// 始めに : を付けておくことで Experiment と
// 同じフォルダにある Module1.ipf をインクルードする
#include ":Module1"

// 初期化処理でコールバック関数を登録する
function initialize()
    NewDataFolder/O root:Packages
    NewDataFolder/O root:Packages:Module1
    string/g root:Packages:Module1:ImageClickProc = "ImageClick"
end

function ImageClick(x, y)
variable x, y

    // 画像がクリックされると呼び出されるので、
    // ここで望みの処理を行う

end

のようにします。

こうすることで、モジュール側のコードをいじることなく、 クリックされたときの動作を差し替えることができるため、 コードの再利用が可能となります。特に、Module1 が ImageClick などのコールバック関数に依存しなくなるため、 モジュールの独立性が向上することがうれしいところです。

コールバック関数呼び出し用関数 †

以下のような一連の関数を作っておくと、 上記のようなフック関数を呼び出すときに便利に使えます。

動作としては、SVAR の名前（上の例で言えば "root:Packages:Module1:ImageClickProc"） を与えると、その SVAR の中身を調べ、そこに関数名が指定されていればそれを呼び出す、 というものになります。

FUNCREF で関数を呼び出すには関数形に合わせてそれぞれコードを書かなければならないですが、 下記のように、
引数無しで数値を返す関数を func2N,
引数無しで文字列を返す関数を func2S,
数値を１つ与えて数値を返す関数を funcN2N,
数値を１つ与えて文字列を返す関数を funcN2S,
数値を２つ与えて数値を返す関数を funcNN2N,
数値を１つ、文字列を２つ与えて数値を返す関数を funcNSS2N,
などと名前を付けると分かりやすそう。

funcXX2X の形のプロトタイプ宣言だけでもいろいろ使い道がありますし、 また、命名規約さえ決めてしまえばここに無い形の関数も容易に追加できるはずです。

CallbackUtility.ipf

LANG:Igor(linenumber)
//
// svar_name という名の svar で指定される関数があれば呼び出す
// default_proc を渡すことで、コールバックが指定されていないときの
// 動作を定義可能
// 
// function   CallbackFunc2N(svar_name)
// function/S CallbackFunc2S(svar_name)
// function   CallbackFuncN2N(svar_name, n)
// function/S CallbackFuncN2S(svar_name, n)
// function   CallbackFuncS2N(svar_name, s)
// function/S CallbackFuncS2S(svar_name, s)
// function   CallbackFuncNN2N(svar_name, n1, n2)
// function/S CallbackFuncNN2S(svar_name, n1, n2)
//
// default_proc を渡すときは、
//     string svar_name = "root:Packages:ModuleName:SomeCallbackProc"
//     CallbackFunc2N(svar_name, default_proc=some_proc)
// のようにする

#pragma rtGlobals=1     // Use modern global access method.
#pragma ModuleName= CallbackUtility

function func2N()
end

function/S func2S()
end

function funcN2N(n)
variable n
end
                                
function/S funcN2S(n)
variable n
end

function funcS2N(s)
string s
end

function/S funcS2S(s)
string s
end

function funcNN2N(n1, n2)
variable n1, n2
end

function/S funcNN2S(n1, n2)
variable n1, n2
end

// svar_name という名の svar で指定される関数があれば proc_name に関数名を返す
static function CallbackFuncExists(svar_name, proc_name)
string svar_name, &proc_name
    SVAR/Z ProcName = $svar_name
    if(SVAR_exists(ProcName) && exists(ProcName)==6)
        proc_name = ProcName
        return 1
    endif
    return 0
end

function CallbackFunc2N(svar_name, [default_proc])
string svar_name
FUNCREF func2N default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF func2N ProcRef = $proc_name
        return ProcRef()
    elseif (paramisdefault(default_proc))
    	return default_proc()
    endif
    return Nan
end

function/S CallbackFunc2S(svar_name, [default_proc])
string svar_name
FUNCREF func2S default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF func2S ProcRef = $proc_name
        return ProcRef()
    elseif (paramisdefault(default_proc))
    	return default_proc()
    endif
    return ""
end

function CallbackFuncN2N(svar_name, n, [default_proc])
string svar_name
variable n
FUNCREF funcN2N default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcN2N ProcRef = $proc_name
        return ProcRef(n)
    elseif (paramisdefault(default_proc))
    	return default_proc(n)
    endif
    return Nan
end

function/S CallbackFuncN2S(svar_name, n, [default_proc])
string svar_name
variable n
FUNCREF funcN2S default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcN2S ProcRef = $proc_name
        return ProcRef(n)
    elseif (paramisdefault(default_proc))
    	return default_proc(n)
    endif
    return ""
end

function CallbackFuncS2N(svar_name, s, [default_proc])
string svar_name, s
FUNCREF funcS2N default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcS2N ProcRef = $proc_name
        return ProcRef(s)
    elseif (paramisdefault(default_proc))
    	return default_proc(s)
    endif
    return Nan
end

function/S CallbackFuncS2S(svar_name, s, [default_proc])
string svar_name, s
FUNCREF funcS2S default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcS2S ProcRef = $proc_name
        return ProcRef(s)
    elseif (paramisdefault(default_proc))
    	return default_proc(s)
    endif
    return ""
end

function CallbackFuncNN2N(svar_name, n1, n2, [default_proc])
string svar_name
variable n1, n2
FUNCREF funcNN2N default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcNN2N ProcRef = $proc_name
        return ProcRef(n1, n2)
    elseif (paramisdefault(default_proc))
    	return default_proc(n1, n2)
    endif
    return Nan
end

function/S CallbackFuncNN2S(svar_name, n1, n2, [default_proc])
string svar_name
variable n1, n2
FUNCREF funcNN2S default_proc
    string proc_name
    if( CallbackFuncExists(svar_name, proc_name) )
        FUNCREF funcNN2S ProcRef = $proc_name
        return ProcRef(n1, n2)
    elseif (paramisdefault(default_proc))
    	return default_proc(n1, n2)
    endif
    return ""
end

使用例：上記の例を書き換え

LANG:Igor
// 画像をクリックしたときにモジュール内で呼び出される。
// 必要に応じてユーザー指定のコールバック関数を呼ぶ
static function ImageClicked(x, y)
variable x, y
    // モジュール名と同じ名前のデータフォルダー root:Packages:Module1 に 
    // ImageClickProc という文字列変数が定義されていて
    // その文字列が示す名前のユーザー定義関数が存在するなら
    // その関数を呼び出す
    CallbackFuncNN2N("root:Packages:Module1:ImageClickProc", x, y)
end