#pragma rtGlobals=1		// Use modern global access method.

//
// usage:
//
//	FileListBox("DoubleClickCallback", FileInfoProc="FileInfoCallBack", FileExt=".dat", InitialPath="C:MyData:", SingleClick=0)
//
//		first param: 
//			Name of callback function that is callbacked when file name is double clicked.
//		FileInfoProc: (optional)
//			Name of callback function that is calledback when file information is required.
//		FileExt: (optional)
//			File extention to filter file names. Specify it in ".ext" style.
//		InitialPath: (optional)
//			Default file path.
//      SingleClick: (optional)
//         If set 1, the proc is called when the file is single clicked
//
// with following functions:
//
//	Function DoubleClickCallback(FileName)
//		string FileName
//		printf "'%s' was double clicked!", FileName
//		print ""
//	end
//	
//	function/T FileInfoCallback(FileName)
//	string FileName
//		// return file infomations separated with semicolon(s) ";"
//		return "a;b"
//	end
//	
// CHANGELOG:
//
// 2013-02-21
//     DoubleClickCallback 内でデータフォルダを移動した場合に反映される
//     ように、Callback 直後に old_datafolder= getdatafolder(1) すること
//     にした
//

function/T DummyFileInfoCallback(FileName)
string FileName
	// return file infomations separated with semicolon(s) ";"
	return ""
end

Function DummyDoubleClickCallback(FileName)
	string FileName
	printf "'%s' was double clicked!", FileName
	print ""
end

function/T UniqueList(list)
string list
    variable i
    for(i=0;i<ItemsInList(list)-1;i+=1)
        if(cmpstr(StringFromList(i,list), StringFromList(i+1,list))==0)
            list=RemoveListItem(i+1,list)
        endif
    endfor
    return list
end

Function SetFilePathProc(ctrlName,varNum,varStr,varName) : SetVariableControl
	String ctrlName
	Variable varNum
	String varStr
	String varName

	string old_datafolder= getdatafolder(1)
	setdatafolder root:FileListBox

	string/g FilePath
	GetFileFolderInfo/D/Q FilePath
	if( V_Flag || !V_isFolder )
		return 0
	endif
	FilePath= S_Path
	
	NewPath/Q/O FilePath_ FilePath
	string/g FileExtention
	string files=""
	variable i
	for(i=0;i<ItemsInList(FileExtention);i+=1)
    	files+= IndexedFile(FilePath_, -1, StringFromList(i,FileExtention))
    endfor
	KillPath/Z FilePath_
	files = UniqueList(SortList(files,";",16))
	
	wave/T FileNames
	Redimension/N=((ItemsInList(files)),1) FileNames

	for(i=0; i<ItemsInList(files); i+=1)
		string/g FileInfoProcName
		FUNCREF DummyFileInfoCallback CallbackFunc= $FileInfoProcName
		string/g FilePath
		string infos= CallbackFunc(FilePath + StringFromList(i, files))
		if( DimSize(FileNames,1)<ItemsInList(infos)+1 )
			redimension/N=((ItemsInList(files)),(ItemsInList(infos)+1)) FileNames
		endif
		FileNames[i][0]= StringFromList(i, files)
		variable j
		for(j=0; j<ItemsInList(infos); j+=1)
			FileNames[i][j+1]= StringFromList(j, infos)
		endfor
	endfor

	setdatafolder $old_datafolder
End

Function FileListBoxProc(ctrlName,row,col,event) : ListBoxControl
	String ctrlName
	Variable row
	Variable col
	Variable event	//1=mouse down, 2=up, 3=dbl click, 4=cell select with mouse or keys
					//5=cell select with shift key, 6=begin edit, 7=end

	string old_datafolder= getdatafolder(1)
	setdatafolder root:FileListBox

	// double click
	NVAR SingleClick
	if( (event==3 && !SingleClick) || (event==1 && SingleClick) )
		string/g DoubleClickProcName
		FUNCREF DummyDoubleClickCallback CallbackFunc= $DoubleClickProcName
		string/g FilePath
		wave/T FileNames
		setdatafolder old_datafolder
		CallbackFunc(FilePath + FileNames[row][0])
		old_datafolder= getdatafolder(1)
		setdatafolder root:FileListBox
	endif

	setdatafolder old_datafolder
	return 0
End

Function FileListBoxPanelHook (infoStr)
	String infoStr
	Variable statusCode= 0

	string old_datafolder= getdatafolder(1)
	setdatafolder root:FileListBox

	// resize controls
	String event= StringByKey("EVENT",infoStr)
	if( !cmpstr(event, "resize") )
		GetWindow FileListBoxPanel, wsizeDC
		SetVariable SetFilePath, size={V_right-V_left, 15}, win=FileListBoxPanel
		ListBox FileListBox, size={V_right-V_left, V_bottom-V_top-25}, win=FileListBoxPanel
	endif
	
	variable cusorx= NumberByKey("MOUSEX", infoStr)
	variable cusory= NumberByKey("MOUSEY", infoStr)
//	setwindow FileListBoxpanel hookcursor=5

	setdatafolder old_datafolder

	return statusCode				// 0 if nothing done, else 1 or 2
End

Window FileListBoxPanel() : Panel
	PauseUpdate; Silent 1		// building window...
	NewPanel /W=(137,57,473,347)
	SetVariable SetFilePath,pos={1,2},size={336,15},proc=SetFilePathProc
	SetVariable SetFilePath,value= root:FileListBox:FilePath
	ListBox FileListBox,pos={1,24},size={336,265},proc=FileListBoxProc
	ListBox FileListBox,listWave=root:FileListBox:FileNames,row= 3,mode= 1
	ListBox FileListBox,row= 3,mode= 1,frame=2
	ListBox FileListBox,userColumnResize= 1
	SetWindow kwTopWin,hook=FileListBoxPanelHook
EndMacro

function FileListBox(DoubleClickProc, [FileInfoProc, InitialPath, FileExt, SingleClick])
string DoubleClickProc
string FileInfoProc
string InitialPath
string FileExt
variable SingleClick

	if( ParamIsDefault(FileInfoProc) )
		FileInfoProc= "DummyFileInfoCallback"
	endif
	if( ParamIsDefault(InitialPath) )
		InitialPath= ""
	endif
	if( ParamIsDefault(FileExt) )
		FileExt= "????"
	endif 
	if( ParamIsDefault(SingleClick) )
		SingleClick= 0
	endif 

	string old_datafolder= getdatafolder(1)
	newdatafolder/o/s root:FileListBox

	make/N=(0,0)/T/O FileNames
	string/g root:FileListBox:FileExtention= FileExt
	string/g root:FileListBox:DoubleClickProcName= DoubleClickProc
	string/g root:FileListBox:FileInfoProcName= FileInfoProc
	string/g root:FileListBox:FilePath= InitialPath
	variable/g root:FileListBox:SingleClick = SingleClick
	
	DoWindow FileListBoxPanel
	if(!V_Flag)
		Execute("FileListBoxPanel()")
	endif
	
	setdatafolder $old_datafolder
end