ソフトウェア/Igor/文字列関連

標準のリスト・ペア関数 †

もっとも一般的なのは、
StringFromList, NumberFromList, ItemsInList などのリスト関数や、
StringByKey, NumberByKey などのペア関数を使う方法です。

例えば、

LANG:Igor
print ItemsInList("test1,test2,test3,test4", ",")
// prints 4
print StringFromList(1, "test1,test2,test3,test4", ",")
// prints "test2"
print StringByKey("key2", "key1:value1\nkey2:value2\n", ":", "\n")
// prints "value2"

と言った具合です。

カンマ区切り値(CSV)などを処理するのはこれらで十分です。

正規表現を使うなら SplitString †

また、同様の目的で SplitString が使えることも多いです。

SplitString は名前に反して、 通常の正規表現の後方参照を文字列変数に受け取るための関数なので、 GrepString でマッチした部分を取り出せずにがっかりしている場合に便利です。

多くの言語で Split は与えられた文字列をデリミタで分けて 配列にして返す関数なので、Igor でのこの名前の付け方はどうかと思うのですが・・・

例として、"key1 = value1, value2 ; comment1" という文字列を、
"=" および ";" を区切り文字として、
"key1", "valu1, value2", "comment1"
の３つに分けることを考えます。

SplitString を使うとこんな風に簡単にできます。

LANG:Igor
function TestSplitString()
    string k, v, c
    string input = "key1 = value1, value2 ; comment1"
    SplitString/E="^(.*?)\s*=\s*(.*?)\s*;\s*(.*?)$" input, k, v, c
    print V_Flag
    // prints 3
    printf "[%s] [%s] [%s]", k, v, c
    // prints "[key1] [value1, value2] [comment1]"
end

地道に切り分けるならこんな方法も †

もっとややこしい文字列を分解するには、 以下の TakeUntil が便利に使えることもあります。

この関数は、

• 与えた文字列の先頭から、
• 指定した区切り文字の直前までを返り値とし、
• 元の文字列変数には区切り文字までを取り去った結果が残ります

長い文字列に対して連続して呼び出すことで次々に値を取り出せます。

• 値を返す際、区切り文字の前後の空白は取り除かれます
  • そのため、上で定義した Trim() という関数を中で使っています

使用例

LANG:Igor(linenumber)
function TestTakeUntil()

    // 任意フォーマットの文字列
    string s = "key1 = value1, value2 ; comment1"
    printf "[%s]\r", s
    // prints "[key1 = value1, value2 ; comment1]"
    
    // 始めて見付かる区切り文字までを取り去って返す
    // 区切り文字前後の空白は消去される
    printf "[%s]  [%s]\r", TakeUntil(s, "="), s
    // prints "[key1]  [value1, value2 ; comment1]"

    // 指定した以外の区切り文字は無視する
    // 内部の空白は保存される
    printf "[%s]  [%s]\r", TakeUntil(s, ";"), s
    // prints "[value1, value2]  [comment1]"

    // 指定した区切り文字が見付からなければすべてを取り去って返す
    printf "[%s]  [%s]\r", TakeUntil(s, ","), s
    // prints "[comment1] []"

end

コード

LANG:Igor(linenumber)
function/T TakeUntil(s, delim)
string &s, delim
    variable d = StrSearch(s, delim, 0)
    string result
    if (d < 0)
        result = Trim(s)
        s = ""
        return result
    endif
    result = Trim(s[0, d-1])
    s = Trim(s[d+strlen(delim), inf])
    return result
end

この関数、s を変更するのではなく検索開始位置を i に与えることとして、 次のようにする手もありますね。
文字列の再確保が必要ない分、この方が動作が高速かもしれません。

LANG:Igor(linenumber)
function/T TakeUntil2(s, delim, i)
string s, delim
variable &i
    variable d = StrSearch(s, delim, i)
    string result
    if (d < 0)
        result = Trim(s[i, inf])
        i = strlen(s)
        return result
    endif
    result = Trim(s[i, d-1])
    i = d + strlen(delim)
    return result
end

function TestTakeUntil2()

    // 任意フォーマットの文字列
    string s = "key1 = value1, value2 ; comment1"
    printf "[%s]\r", s
    // prints "[key1 = value1, value2 ; comment1]"
    
    // 始めて見付かる区切り文字までを取り去って返す
    // 区切り文字前後の空白は消去される
    variable i = 0
    printf "[%s]  [%s]\r", TakeUntil2(s, "=", i), s[i, inf]
    // prints "[key1]  [ value1, value2 ; comment1]"

    // 指定した以外の区切り文字は無視する
    // 内部の空白は保存される
    printf "[%s]  [%s]\r", TakeUntil2(s, ",", i), s[i, inf]
    // prints "[value1, value2]  [ comment1]"

    // 指定した区切り文字が見付からなければすべてを取り去って返す
    printf "[%s]  [%s]\r", TakeUntil2(s, ",", i), s[i, inf]
    // prints "[comment1] []"

end