箱の中の自由粒子/メモ のバックアップ(No.1)

更新


概要

量子力学I/箱の中の自由粒子? のページの補足です。

非定常状態の解

Mathematica ソース

LANG:mathematica
Sum[(1/n!)^2, {n, Infinity}]
(* output: -1 + BesselI[0, 2] *)

psi[x_, t_] := Sqrt[2/(BesselI[0, 2] - 1)] Sum[Exp[I n^2 t] Sin[n Pi x]/n!, {n, 50}]

Module[{t = 0},
  Show[{
    Plot[ Abs[psi[x, t]]^2, {x, 0, 1}, 
      BaseStyle -> {FontSize -> 18}, ImageSize -> Large, PlotRange -> {0, 3}],
    Graphics[Text["t = " <> ToString[t], {0.8, 2.8}, {-1, 0}]]
  }]
]

anim = Table[
  Show[{
    Plot[ Abs[psi[x, t]]^2, {x, 0, 1}, 
      BaseStyle -> {FontSize -> 18}, ImageSize -> Large, PlotRange -> {0, 3}],
    Graphics[Text["t = " <> ToString[t], {0.8, 2.8}, {-1, 0}]]
  }], {t, 0, 10, 0.02}
];
Export["time-dependent.gif", anim, "GIF"]

Show[{
  DensityPlot[ Abs[psi[x,t]]^2, {x, 0, 1}, {t, 0, 10}, 
    PlotPoints -> 100, ImageSize -> Large],
  ParametricPlot[
    { NIntegrate[x Abs[psi[x, t]]^2, {x, 0, 1}], t}, 
    {t, 0, 10}, PlotPoints -> 40, ImageSize -> Large, PlotStyle -> {Thick, Red}]
}, BaseStyle -> {FontSize -> 18}]

1次元の箱の中の自由粒子(有限ポテンシャル)

詳しい導出過程

#ref(): File not found: "continuous.png" at page "量子力学I/箱の中の自由粒子"

k=\sqrt{2mE}/\hbar k'=\sqrt{2m(V-E)}/\hbar に対して、

  • 箱の左: \psi_1(x)=Ce^{k'x}
  • 箱の中: \psi_1(x)=Ae^{ikx}+Be^{-ikx}
  • 箱の右: \psi_3(x)=De^{-k'x}

境界条件は、

  • \psi_1(0)=\psi_2(0) \psi_1'(0)=\psi_2'(0)
  • \psi_2(a)=\psi_3(a) \psi_2'(a)=\psi_3'(a)

代入すると、

C=A+B k'C=ik(A-B) より \frac{A-B}{A+B}=\frac{k'}{ik}

Ae^{ika}+Be^{-ika}=De^{-k'a} ik(Ae^{ika}-Be^{-ika})=-k'De^{-k'a} より \frac{Ae^{ika}-Be^{-ika}}{Ae^{ika}+Be^{-ika}}=-\frac{k'}{ik}

したがって、

  -\frac{A-B}{A+B}=\frac{Ae^{ika}-Be^{-ika}}{Ae^{ika}+Be^{-ika}}

  -(A-B)(Ae^{ika}+Be^{-ika})=(A+B)(Ae^{ika}-Be^{-ika})

  A^2e^{i2ka}=B^2)

  B=\pm Ae^{ika})

を得る。これを上の式に代入すれば C=A(1\pm e^{ika}) D=Ae^{k'a}(e^{ika}\pm 1) であり、 さらに k'C=ik(A-B) より k'(1\pm e^{ika})=ik(1\mp e^{ika}) を得る。

 &math( \psi_1(x)&=A(e^{ikx}\pm e^{ka}e^{-ikx})\\ &=Ae^{ka/2}(e^{ik(x-a/2)}\pm e^{-ik(x-a/2)})\\ &=2Ae^{ka/2}\frac{e^{ik(x-a/2)}\pm e^{-ik(x-a/2)}}{2}\\ );

  C=2Ae^{ka/2}\frac{e^{-ika/2}\pm e^{ika/2}}{2}

  D=2Ae^{ka/2}\,e^{k'a}(e^{ika/2}\pm e^{-ika/2})

  (k'a/2)\frac{e^{-ika/2}\pm e^{ika/2}}{2}=i(ka/2)\frac{e^{-ika/2}\mp e^{ika/2}}{2}

より、

[複号の上を取れば]

  \psi_1(x)=2Ae^{ka/2}\cos\big(k(x-a/2)\big)

  C=2Ae^{ka/2}\cos(ka/2)

  D=2Ae^{ka/2}\,e^{k'a}\cos(ka/2)

  (k'a/2)\cos(ika/2)=(ka/2)\sin(ka/2)

[複号の下を取れば]

  \psi_1(x)=2iAe^{ka/2}\sin\big(k(x-a/2)\big)

  C=-2iAe^{ka/2}\sin(ka/2)

  D=2iAe^{ka/2}\,e^{k'a}\sin(ka/2)

  -(k'a/2)\sin(ka/2)=(ka/2)\cos(ka/2)

のように、それぞれ x=a/2 を中心に \cos 的、 \sin 的な波動関数となる。

k,k' についての条件式の両辺を二乗した上で k'^2+k^2=\frac{2mV}{\hbar^2} の関係を使って書き直せば、

[ \cos 的な関数について]

  (ka/2)^2(1+\tan^2(ka/2))=\frac{mVa^2}{2\hbar^2} ただし \tan(ka/2)>0

[ \sin 的な関数について]

  (ka/2)^2(1+\cot^2(ka/2))=\frac{mVa^2}{2\hbar^2} ただし \tan(ka/2)<0

を得る。

Mathematica ソース

LANG:mathematica
Plot[{
  If[Tan[x] < 0, Infinity, x^2 (1 + Tan[x]^2)],
  If[Cot[x] > 0, Infinity, x^2 (1 + Cot[x]^2)]}, 
  {x, 0, 14}, 
  PlotRange -> {0, 200}, BaseStyle -> {FontSize -> 18}, ImageSize -> Large, 
  PlotLegends -> Placed[{"cos 的", "sin 的"}, Above],
  AxesLabel -> {ka/2, mVa^2/(2 \[HBar]^2)}]

NSolve[x^2 (1 + Tan[x]^2) == 50 && Tan[x] > 0 && 0 < x < 10, x, WorkingPrecision -> 15]
(* {{x -> 1.37508316964374}, {x -> 4.09477807780528}, {x -> 6.63585976688118}} *)

NSolve[x^2 (1 + Cot[x]^2) == 50 && Cot[x] < 0 && 0 < x < 10, x, WorkingPrecision -> 15]
(* {{x -> 2.74319088650076}, {x -> 5.41164383515459}} *)

coslike[x_, k_] := Module[{k2 = Sqrt[4 50 - k^2]},
  Sign[k] If[x < 0, Cos[k/2] Exp[k2 x], 
     If[x < 1, Cos[k (x - 1/2)], Cos[k/2] Exp[-k2 (x - 1)]]] 10 + k^2
 ]

sinlike[x_, k_] := Module[{k2 = Sqrt[4 50 - k^2]},
  If[x < 0, -Sin[k/2] Exp[k2 x], 
     If[x < 1, Sin[k (x - 1/2)], Sin[k/2] Exp[-k2 (x - 1)]]] 10 + k^2
]
 
Plot[{
 coslike[x, 2 1.37508316964374341419334462792217407823`15.],
 sinlike[x, -2 2.74319088650075787031867823175879453346`15.],
 coslike[x, -2 4.0947780778052791609523226938312581713`15.],
 sinlike[x, 2 5.41164383515459114436056269363192749999`15.],
 coslike[x, 2 6.63585976688118310914259741089030967404`15.]
 },
 {x, -0.5, 1.5}, PlotRange -> {0, 300}, ImageSize -> Large, 
  BaseStyle -> {FontSize -> 20},
  Axes -> {True, False}, 
  PlotStyle -> {Thick, Thin, Thin, Thin, Thin, Thin},
  AspectRatio -> 1
]

sin[x_, n_] := If[x < 0, 0, If[x > 1, 0, Sin[n Pi x]]] 10 + (n Pi)^2

Plot[{If[x < 0, 500, If[x < 1, 0, 500]],
 sin[x, 1], sin[x, 2], sin[x, 3], sin[x, 4], sin[x, 5] },
 {x, -0.5, 1.5}, PlotRange -> {0, 300}, ImageSize -> Large, 
 BaseStyle -> {FontSize -> 20},
 Axes -> {True, False}, 
 PlotStyle -> {Thick, Thin, Thin, Thin, Thin, Thin}, 
 AspectRatio -> 1
]

Counter: 43798 (from 2010/06/03), today: 13, yesterday: 0